Регистр процессора

Регистр процессора — это поле определённой длины, которое находится в памяти процессора. Доступ к регистру очень быстр, его содержимое можно сохранить в память и обратно. Бывает как доступен из программы, так и нет.

Язык ассемблера

Язык ассемблера — это низкоуровневый язык программирования, максимально приближённый к командам самого процессора.

Ассемблерная директива

Ассемблерная директива («псевдокоманда») — это команда ассемблера. Директивы влияют на компиляцию программы. Примеры в Makexm2c — .skip, .ascii и .def.

Данный учебник учит программированию на Makexm2c.

Makexm2c — это язык ассемблера, предназначенный для создания программ под iiixmish2. Бо́льшая часть команд Makexm2c представляет собой мнемонические обозначения инструкций iiixmish2. Важно упомянуть, что в большинстве инструкций типы параметров определены. Например, для add применимы только регистры; для mov — регистр и константа.

Iiixmish2 — это 32-разрядная компьютерная архитектура. Она имеет >=10 миллионов ячеек памяти, 44 пользовательских регистров, 2000 ячеек видеопамяти, более 30 команд и экран 63x30 символов.^[1]

Ниже представлены названия iiixmish2-инструкций и соответствующие signed char-опкоды^[2]:

Скачайте свободную реализацию iiixmish2 здесь, а также ассемблер здесь. Раньше мы предлагали читателям загрузить makexm2c-tools, но сейчас он устарел. Ассемблер, входящий в старый комплект, был заменён новым и быстрым mxm2c-as.

Распакуйте полученные архивы. Скомпилируйте программы, используя OpenJDK 17 и GCC. В Debian, Вы можете установить его, выполнив следующую команду:

$ sudo apt install openjdk-17-jdk

Выполните java --version.

Makexm2c-программы могут состоять из команд:

<название> [<аргумент 0>[[,] <аргумент 1>]…]

, псевдокоманд (директив):

.<название> [<аргумент 0>[ <аргумент 1>]]

, меток:

<название>:

и комментариев.

К регистрам можно подставлять «UR» (UR0, UR1…).

Теперь мы можем написать первую программу. Она будет выводить на экран компьютера «hello, world».

Создайте файл «hello.s» и вставьте в него следующее:

mov UR0, <main>
jmp UR0

;;;;;  данные  ;;;;;

str:
    .skip 12
    .ascii <str> "hello, world"
    .byte 0

;;;;;;;;;;;;;;;;;;;;

main:
    mov UR0, <str>
    mov UR6, 0
loop:
    ild UR0, UR8
    mov UR10, 0
    mov UR11, <final>
    if UR8 == UR10, UR11
    vsv UR8, UR6
    inc UR0
    inc UR6
    mov UR11, <loop>
    jmp UR11
final:
    updd

Это код на Makexm2c, переведите его в код, понятный iiixmish2, используя ассемблер:

$ mxm2c-as hello.s hello

Отлично! Запустите виртуальную машину, передав полученный файл:

$ java downadow.iiixmish2.main.Iiixmish2 hello

Данная программа записывает строку str в видеопамять до тех пор, пока не встретится нулевой байт, после чего переходит к final и обновляет экран. Конец программы.

Инструкция JMP выполняет переход к адресу, который извлекается из заданного регистра. Существует также команда CALL, имеющая форму call регистр, адрес, где первый операнд — регистр, в который будет (если не 0) положен следующий после инструкции адрес (то есть PC+1), а второй — адрес, на который надо перейти (например, <label>).

Как уже было сказано ранее, iiixmish2 имеет 44 пользовательских регистров (п. реги́стры).

Избегайте использования п. регистров 2, 3, 4 и 5, т. к. они могут использоваться некоторыми командами.^[2]

Команда mov сохраняет число в п. регистр, число не должно превышать один байт. Аргументы:

Пример использования:

mov UR10, 64

Также можно вставлять 'СИМВОЛ' вместо числа, пример:

mov UR10, 'j'

то же, что и

mov UR10, 106

Команда add складывает два п. регистра, сохраняет результат в п. регистр. Аргументы:

Пример использования:

add UR0 UR6, UR9

Запятые между аргументами и «UR» к адресам, — необязательны.

Команда sub вычитает из п. регистра значение другого п. регистра, результат сохраняется в п. регистр. Аргументы:

Пример использования:

sub UR6 UR8, UR0

Команда ld загружает значение п. регистра в другой п. регистр. Аргументы:

Пример использования:

ld UR1, UR0

Команда mul умножает п. регистр на другой п. регистр, результат сохраняется в п. регистр. Аргументы:

Пример использования:

mul UR6 UR8, UR0

Команда div делит п. регистр на другой п. регистр, результат сохраняется в п. регистр. Аргументы:

Пример использования:

div UR6 UR8, UR0

Команда mod делит п. регистр на другой п. регистр, остаток сохраняется в п. регистр. Аргументы:

Пример использования:

mod UR0 UR29, UR8

Команда inc увеличивает п. регистр на единицу. Пример использования:

inc UR0

Команда dec уменьшает п. регистр на единицу. Пример использования:

dec UR0

Команда tnp изменяет знак п. регистра, пример использования:

tnp UR14

mov2 — синоним mov. Не используйте его в новом коде.

Следующий код выполняет операцию вида UR20 << UR19 (сдвиг битов влево) и сохраняет результат в UR8:

lshift UR20 UR19, UR8

UR8 = UR20 >> UR19:

rshift UR20 UR19, UR8

Для побитовых XOR, OR и AND, используйте одноимённые инструкции.

Команда time копирует в заданный регистр кол-во миллисекунд, приблизительно начиная от запуска процессора. Принимает один аргумент. trst сбрасывает время.

Коммента́рий — это текст в коде программы, который не влияют на её работу, но, как правило, помогает лучше понять её. В Makexm2c комментарии могут быть разных видов.^[3]

Ме́тки — в Makexm2c — это неотъемлемая часть языка. Обращение к метке вставляет на месте обращения адрес, по которому располагается эта метка в двоичной форме программы. Пример:

метка:
    nop
    nop
    mov UR0, <метка>

Для обращения, название метки, заключённое в < и >, вставляется в нужное место в программе.

Для создания именованных констант используется директива .def, пример:

.def %CONST% "0"

создаст именованную константу «CONST» со значением «0».

Обращение к именованным константам отличается от обращения к меткам лишь тем, что название заключается в %, а не < и >.

В iiixmish2 есть команды для создания условных переходов. Рассмотрим, как использовать их в Makexm2c.

В iiixmish2 нет инструкций вроде BRz, BRn и т. д., ветвление реализуется посредством команд IFA, IFB, IFC и IFD. Для создания перехода вроде «если значение п. регистра А равно значению регистра Б, то выполнить переход на <значение п. регистра В>», воспользуйтесь следующей конструкцией:

if АДРЕС0 == АДРЕС1, АДРЕС2

Ясно? Идём дальше.

if АДРЕС0 != АДРЕС1, АДРЕС2

if АДРЕС0 > АДРЕС1, АДРЕС2

if АДРЕС0 < АДРЕС1, АДРЕС2

Как уже говорилось во введении, iiixmish2 имеет 2000 ячеек видеопамяти.

Почти все ячейки видеопамяти могут отображаться на экране. Последние две ячейки, — 1998-ая и 1999-ая, — хранят параметр цвета для фона и параметр цвета для отображаемых ячеек видеопамяти. Возможные цвета^[2]:

Пример изменения цвета отображаемых ячеек видеопамяти на жёлтый:

mov UR0, 7
vsv UR0, 1999

Для загрузки значения из видеопамяти в п. регистр, используйте команду vld. Её аргументы:

Пример использования:

vld 0001, UR8

Для сохранения значения п. регистра в ячейку видеопамяти, используйте vsv. Аргументы:

Пример использования:

vsv UR0, 0063

Вы также можете вписывать адрес п. регистра вместо ЦЦЦЦ в аргументах этих команд (такое поддерживается в Makexm2c). Так, vsv UR0, UR16 сохранит содержимое п. регистра 0 в яч. видеопамяти, адрес которой находится в регистре 16.

Вы можете печатать разными цветами! Для этого, измените ячейку видеопамяти, на месте которой будет изменение цвета последующих, на 255 плюс нужное значение цвета.^[2]

Программы iiixmish2 загружаются в его па́мять (насколько это возможно).^[2] Ограничения кода вне 0-65535:

1. нельзя читать/прыгать/писать в 0-65535
2. нельзя читать 9999872-9999999
3. нельзя изменять 9999000-9999099
4. действие инструкции OFF равно переходу к 32768

Команда ild предназначена для загрузки значений из памяти в п. регистры. Аргументы:

Пример использования:

ild 6001900, UR0

Для сохранения значения п. регистра в память, используйте isv. Аргументы:

Пример использования:

isv UR10, 0999999

Вы можете вписывать адрес п. регистра вместо ЦЦЦЦЦЦЦ в аргументах этих команд.

Ниже представлен пример программы, в которой пользователь может вводить данные. То, что от символа «;» до конца строки будет комментарием.

mov UR28, <loop>
; указатель вывода
mov UR27, 0
; ноль
mov UR0, 0

loop:
    ; эта команда ничего не делает,
    ; её выполнение может занимать
    ; до миллисекунды
    nop
    ; проверка клавиши
    if UR1 == UR0, UR28
    ; сохраняем символ
    vsv UR1, UR27
    ; увеличиваем указатель
    inc UR27
    ; сбрасываем регистр клавиатуры
    mov UR1, 0
    ; обновляем экран
    updd
    
    ; продолжение
    jmp UR28

Вариант «hello, world» с функциями:

.def %R_OUTPUT% "UR42"
.def %R_RETURN% "UR43"

mov %R_OUTPUT%, 0
mov UR0, <main>
jmp UR0

string:
    .skip 16
    .ascii <string> "hello, world"

main:
    mov UR0, <string>
    call %R_RETURN%, <puts>
    
    call %R_RETURN%, <halt>

puts:
    ild UR0, UR8
    mov UR10, 0
    mov UR11, <_puts_final>
    if UR8 == UR10, UR11
    vsv UR8, %R_OUTPUT%
    inc UR0
    inc %R_OUTPUT%
    mov UR11, <puts>
    jmp UR11
_puts_final:
    updd
    jmp %R_RETURN%

halt:
    mov UR0, <halt>
    jmp UR0

.ascii <mem0> "hello world" приказывает ассемблеру записать строку «hello world», начиная с яч. <mem0> (адрес метки mem0). .skip N пропускает N байтов, это похоже на N nop'ов. .byte ЧИСЛО вставит десятичное ЧИСЛО. .orig 1000 выполнит переход к ячейке 1000 (следующий после этого код будет записан, начиная с ячейки 1000).

Iiixmish2 и другие компьютеры (включая ЭВМ, на котором выполняется iiixmish2) могут «общаться» через порты ввода/вывода. Данные, которые передал компьютер, сохраняются в памяти iiixmish2, начиная с адреса 9999872. Чтобы ответить, запишите краткий ответ, начиная с адреса 9999000.

Это последний раздел изучения. В нём описываются команды off и vrst.

Если off выполняется в коде 0-65535, то он завершает работу iiixmish2; иначе выполняется переход к 32768.

vrst заменяет значения почти всех ячеек видеопамяти на неотображаемое (0), предназначение — убрать текст с экрана.